Initial fluctuations (for Lemma 4.3)

pi[j_]:=(E^(-c))(c^j)/j!

cov[j_,k_]:=pi[j]pi[k]((((j-c)(k-c))/c)-1)

(Subscript[Σ, 1,1])=cov[1,1]+pi[1];
(Subscript[Σ, 1,2])=(Subscript[Σ, 2,1])=Sum[cov[1,k],{k,2,∞}];
(Subscript[Σ, 1,3])=(Subscript[Σ, 3,1])=Sum[(k/2) cov[1,k],{k,0,∞}]+pi[1]/2;
(Subscript[Σ, 2,2])=Sum[cov[j,k],{j,2,∞},{k,2,∞}]+Sum[pi[j],{j,2,∞}];
(Subscript[Σ, 2,3])=(Subscript[Σ, 3,2])=Sum[(k/2) cov[j,k],{j,2,∞},{k,0,∞}]+Sum[(j/2) pi[j],{j,2,∞}];
(Subscript[Σ, 3,3])=Sum[(j/2)(k/2) cov[j,k],{j,0,∞},{k,0,∞}]+Sum[(((j/2))^2)pi[j],{j,0,∞}];

Table[(Subscript[Σ, i,j]),{i,3},{j,3}]//Simplify//MatrixForm

Estimating the fluid limit (for Section 5.1)

f[u_]:=(E^u)-u-1

(Subscript[F, 1])[x1_,x2_,x3_]:=-1-(x1/(2x3))+(((x2^2)((z[x1,x2,x3])^4)(E^(z[x1,x2,x3])))/(((2x3 f[z[x1,x2,x3]]))^2))-((x1 x2 ((z[x1,x2,x3])^2)(E^(z[x1,x2,x3])))/((((2x3))^2)f[z[x1,x2,x3]]));
(Subscript[F, 2])[x1_,x2_,x3_]:=-1+(x1/(2x3))-(((x2^2)((z[x1,x2,x3])^4)(E^(z[x1,x2,x3])))/(((2x3 f[z[x1,x2,x3]]))^2));
(Subscript[F, 3])[x1_,x2_,x3_]:=-1-((x2 ((z[x1,x2,x3])^2)(E^(z[x1,x2,x3])))/(2x3 f[z[x1,x2,x3]]));

β[z_]:=ProductLog[c (E^z)]/c

(The Mathematica command for the Lambert W function is “ProductLog”.)

(Subscript[chi, 1])[z_]:=(1/c)((z^2)-z c β[z](1-(E^(-z))));
(Subscript[chi, 2])[z_]:=(1-(1+z)(E^(-z)))β[z];
(Subscript[chi, 3])[z_]:=(1/(2c))(z^2);

Now, let’s re-express the drift function in terms of z:

F[z_]:={(Subscript[F, 1])[(Subscript[x, 1]),(Subscript[x, 2]),(Subscript[x, 3])],(Subscript[F, 2])[(Subscript[x, 1]),(Subscript[x, 2]),(Subscript[x, 3])],(Subscript[F, 3])[(Subscript[x, 1]),(Subscript[x, 2]),(Subscript[x, 3])]}/.{z[(Subscript[x, 1]),(Subscript[x, 2]),(Subscript[x, 3])]->z,(Subscript[x, 1])->(Subscript[chi, 1])[z],(Subscript[x, 2])->(Subscript[chi, 2])[z],(Subscript[x, 3])->(Subscript[chi, 3])[z]}

Let’ s do a series expansion (Fact 5.2):

Series[F[z],{z,0,0}]//MatrixForm

Computing ∂F (for Lemma 5.3)

We will need to use implicit differentiation to compute ∂z/∂(Subscript[x, i]), so we introduce a quantity Q, which according to the 

definition of z can be expressed either in terms of z or x .

Q[z_]:=(((-1+(E^z)) z)/(f[z]))
Q[x1_,x2_,x3_]:=((-x1+2 x3)/x2)

(Note that ∂z/∂(Subscript[x, i])=∂Q/∂(Subscript[x, i])·dz/dQ, 

 and dz/dQ is the reciprocal of Q'[z].)

dF=Table[
(D[(Subscript[F, i])[(Subscript[x, 1]),(Subscript[x, 2]),(Subscript[x, 3])],(Subscript[x, j])]/.
{Derivative[1,0,0][z][(Subscript[x, 1]),(Subscript[x, 2]),(Subscript[x, 3])]->Derivative[1,0,0][Q][(Subscript[x, 1]),(Subscript[x, 2]),(Subscript[x, 3])]/Q'[z[(Subscript[x, 1]),(Subscript[x, 2]),(Subscript[x, 3])]],
Derivative[0,1,0][z][(Subscript[x, 1]),(Subscript[x, 2]),(Subscript[x, 3])]->Derivative[0,1,0][Q][(Subscript[x, 1]),(Subscript[x, 2]),(Subscript[x, 3])]/Q'[z[(Subscript[x, 1]),(Subscript[x, 2]),(Subscript[x, 3])]],
Derivative[0,0,1][z][(Subscript[x, 1]),(Subscript[x, 2]),(Subscript[x, 3])]->Derivative[0,0,1][Q][(Subscript[x, 1]),(Subscript[x, 2]),(Subscript[x, 3])]/Q'[z[(Subscript[x, 1]),(Subscript[x, 2]),(Subscript[x, 3])]],
z[(Subscript[x, 1]),(Subscript[x, 2]),(Subscript[x, 3])]->z,(Subscript[x, 1])->(Subscript[chi, 1])[z],(Subscript[x, 2])->(Subscript[chi, 2])[z],(Subscript[x, 3])->(Subscript[chi, 3])[z]}),
{i,3},{j,3}];

Now let’s rewrite in terms of z, and do a series expansion around zero.

Series[dF/.{z[(Subscript[x, 1]),(Subscript[x, 2]),(Subscript[x, 3])]->z,(Subscript[x, 1])->(Subscript[chi, 1])[z],(Subscript[x, 2])->(Subscript[chi, 2])[z],(Subscript[x, 3])->(Subscript[chi, 3])[z]},{z,0,-2}]/.{ProductLog->W}//MatrixForm

Next we want to diagonalise this matrix for Lemma 5.3 . 

  Let’ s first rescale by (z^2) and get rid of the error terms.

H=Limit[(z^2)%,z->0];

H//Eigenvectors//Transpose//MatrixForm

(This is the matrix Q in Lemma 5.3.)

DiagonalMatrix[H//Eigenvalues]//MatrixForm

(This is the matrix D in Lemma 5.3.)